Arduino Robots – A First Attempt!

Mar 4 2011 12:26 PM

Hey Arduinoists everywhere! I am proud to proclaim that I am now one of you!!

The Arduino hardware/software platform is awesome in so many ways and has made my job of entry level robot designer much easier! Let me add that I didn't have any prior experience with building robots. This project has helped me quite a bit to jump start the process. While I still have a lot to learn, I can say that I have very quickly acquired a pretty good base to continue building on. It’s exciting and fun! And so, this is the main reason I am posting this blog entry. Read on …

Making Robots
As I mentioned above, this is the first time I have ever attempted an electronics project of this complexity. I had built a simple timer circuit when I was younger, but not much beyond that. Having a casual interest in robotics for a while, I never felt like I had access to the right tools and tech to approach the subject until I heard about the Arduino microcontroller. I read a bit about what people where doing with them online, watched about a hundred Youtube “Hey I Made a Segway Arduino Robot” videos, and then ordered a few boards, sensors and other starter kit stuff. Once the orders arrived at my doorstep, I commenced to begin the basic exploration via the numerous examples available all over the web. Progressing through, blinking LED’s, onto LCD panel output, and then to the PING)) and Compass sensors.

Although I had a general idea in mind for the mechanical bits, I didn’t really know the best way to go with the microcontroller. My robot (dubbed botZero) grew organically. I worked on particular example problems first and then started connecting parts later. Those boards and pieces of example sketches (Arduino programs) later became my current hardware/software prototype.

Before I go into the details of this design and it’s construction, I want to make reference here of useful resources for beginning Arduino users:

http://arduino.cc ... the master site of the Arduino platform.

Retail websites I used for parts: MakerSHED , Hacktronics
NKC Electronics All Electronics Adafruit Pololu Robot Shop

Design and Construction
About how I first approached the design of this robot ... I didn’t really have a good plan in my head until after I finished a prototype board assembly with the PING and Compass sensors. Once I saw those numbers appear on the LCD panel I rigged, I immediately imagined using that data to steer a three-wheeled robot. Three wheels? Why three? Because, the steering assembly construction appeared to me to be much less complex for a single steering wheel. Plus, I wanted to build it by hand, instead of ordering some chassis kit and assembling that. Don’t get me wrong, those assembly kits seem like great ways to quickly get your project up and running mechanically. But for myself, I was just as interested in the mechanics as in the electronics and control software, so I decided on the tricycle platform for ease of construction.

Now onto the electronics! I will cover the most fundamental points first. At the heart of this design is a pair of Arduino Duemilanove microcontrollers, linked together by a simple serial connection. My robot could have been constructed with a single Arduino board, however, I wanted to make sure I had plenty of room for growth (servos, motors, and various sensors and other micro-peripherals) in the future. Also, I liked the idea of separating the platform into sensor data acquisition and motion control for a more componentized organization. The only problem here is, you can’t just *snap* two of these boards together to make a larger one. They both operate on separate clocks – therefore, I had to create a simple handshaking algorithm for data exchange between the two boards. This was not hard, as like most other things Arduino, there was a good example already on the Arduino site. I will cover the details of the serial communications and handshaking code in a later post, for now let me just say, cross the TX/RX lines and MAKE THAT COMMON GROUND!!

Boards, Sensors, Motors
Now looking at the two Arduinos used in this design, you can see the top most board on the robot is the sensor board. It is connected electrically to a PING))) ultrasonic sensor(ultrasonic echo location chip) and a Hitachi compass module(magnetometer chip). It takes samples from these chips for distance and direction. After each read from these sensors, the data is sent over the serial connection to the second Arduino, the motor control board.

Here is a partial sketch (Arduino program) illustrating the sample collection from the PING)) Sensor :

Note: this code does not show the data communication from the sensor board to the motor control board. That code is contained in complete source archive below.

// PING)))

// the pin number of the sensor output

const byte pingPin = 7;

  

// sensor data values

int inches = 0;

int cm = 0;

  

// PING Sensor driver logic

void pinger_loop()

{

  // variable for duration of the ping

  long duration;

 

  // The PING))) is triggered by a HIGH pulse of 2 

  // or more microseconds. Give a short LOW pulse 

  // beforehand to ensure a clean HIGH pulse:

  pinMode(pingPin, OUTPUT);

  digitalWrite(pingPin, LOW);

  

  delayMicroseconds(2);

  digitalWrite(pingPin, HIGH);

  

  delayMicroseconds(3);

  digitalWrite(pingPin, LOW);

 

  // The same pin is used to read the signal 

  // from the PING))): a HIGH pulse whose duration 

  // is the time (in microseconds) from the sending

  // of the ping to the reception of its echo 

  // off of an object.

  pinMode(pingPin, INPUT);

  duration = pulseIn(pingPin, HIGH);

 

  // convert the time into a distance

  inches = microsecondsToInches(duration);

  cm = microsecondsToCentimeters(duration);

}

  

// PING Scale Functions

long microsecondsToInches(long microseconds)

{

  // According to Parallax's datasheet 

  // for the PING))), there are 73.746 

  // microseconds per inch (i.e. sound 

  // travels at 1130 feet per second).  

  // This gives the distance traveled 

  // by the ping, outbound and return, 

  // so we divide by 2 to get the 

  // distance of the obstacle.

  

  return microseconds / 74 / 2;

}

  

long microsecondsToCentimeters(long microseconds)

{

  // The speed of sound is 340 m/s 

  // or 29 microseconds per centimeter.

  // The ping travels out and back, so 

  // to find the distance of the object

  // we take half of the distance traveled.

  

  return microseconds / 29 / 2;

}

The motor control board also has an Adafruit motor shield attached, which handles all motor and servo control. This motor shield came as a kit in a static bag with some 25+ parts (chips, resistors, capacitors, PCB, etc). I was happy to have successfully soldered the whole together, being that this was my first major small electronics soldering project. The motor shield is supplied an external 9.6 vdc Ni-MH supply that is used for motors control only, servos are still driven off the main onboard 9 vdc supply.

The motor control board is also the main Arduino holding all the control logic which drives user switch input, sensor servo, speed and steering decision control. Here is a partial sketch, containing the steering servo and motor speed control logic:

// DC motors on M3 & M4

AF_DCMotor motorLeft(4);

AF_DCMotor motorRight(3);

  

// DC hobby servos

Servo servoSteering;

Servo servoSensor;

  

byte inches = 0;

byte inches_ahead = 0;

byte inches_left = 0;

byte inches_right = 0;

byte angle = 0;

byte inches_steering = 0;

byte inches_minimum = 99;

  

int steeringAngle = 70;

int sensorAngle = 70;

int sensorStep = -65;

  

boolean stopped = true;

int stoppedTimer = 0;

int motorSlice = 0;

int sensorSlice = 0;

byte motorMode = RELEASE;

int dirchange = 0;

  

const int ledPin = 15;

boolean stateChanged = false;

int lastState = HIGH;

int state = LOW;

  

const int saverPin = 14;

boolean superSaver = false;

boolean highSpeed = false;

  

const int SAVEBATTERY_SENSORSLICE = 64;

const int SAVEBATTERY_MOTORSLICE = 128;

  

int sensor_timeSlices = -1; // disabled 

int motor_timeSlices = -1; // disabled 

  

const int stopSpeed = 0;

const int fwdSpeed = 60;

const int backSpeed = 60;

const int turnSpeed = 70;

const int backSpeed2 = 70;

  

// called from the Arduino Setup fcn

void InitMotorsAndServos(int angle, int mode)

{

  sensorAngle = steeringAngle = angle;

  motorMode = mode;

  

  // init servos

  servoSensor.attach(9);

  servoSensor.write(sensorAngle); 

  servoSteering.attach(10);

  servoSteering.write(steeringAngle); 

  

  // init motors

  motorLeft.setSpeed(0);

  motorRight.setSpeed(0);

  motorLeft.run(motorMode);

  motorRight.run(motorMode);

}

  

// called from the Arduino Loop fcn

void motors_loop()

{

  motorLeft.run(motorMode);

  motorRight.run(motorMode);

  

  if (dirchange > 0)

  {

    dirchange--;

    if (dirchange==0)

    {

      if (motorMode == BACKWARD)

        motorMode = FORWARD;

      else if (motorMode == FORWARD)

        motorMode = BACKWARD;

    }

    return;

  }

  

  change_motorsAcel();

}

  

void change_motorsAcel()

{

  if (stoppedTimer > 0)

  {

    stoppedTimer--;

    return;

  }

  

  if (motorSlice < motor_timeSlices)

  {

    motorSlice++;

    return;

  }

  motorSlice = 0;

  

  if (stopped == false)

  {

    if (inches_steering < 10)

    {

      motors_forward(stopSpeed, steeringAngle);

    }

    else if (inches_left > inches_right && inches_left > inches_ahead)

    {

      inches_steering = inches_left;

      motors_forward(turnSpeed, 5);

    }

    else if (inches_right > inches_left && inches_right > inches_ahead)

    {

      inches_steering = inches_right;

      motors_forward(turnSpeed, 135);

    }

    else

    {

      inches_steering = inches_ahead;

      motors_forward(fwdSpeed, 70);

    }

  }

  else // stopped == true

  {

     if (inches_left > inches_right && inches_left > inches_ahead)

     {

       inches_steering = inches_left;

       if (inches_steering < 5)

       {

          motors_backward(backSpeed, 135);

          dirchange = 3200;

       }

       else

          motors_forward(turnSpeed, 5);

     }

     else

     if (inches_right > inches_left && inches_right > inches_ahead)

     {

       inches_steering = inches_right;

       if (inches_steering < 5)

       {

         motors_backward(backSpeed, 5);

         dirchange = 3200;

       }

       else

          motors_forward(turnSpeed, 135);

     }

     else

     {

       inches_steering = inches_ahead;

       if (inches_steering < 5)

       {

          long r = random(0, 2);

          

          motors_backward(backSpeed2, (r==1 ? 135 : 5));

          dirchange = 3200;

       }

       else

          motors_forward(fwdSpeed, 70);

     }

  }

}

// motors acceleration

  

void set_motors(int mode, int limit)

{

  int spd = limit;

  if (highSpeed)

     spd = (spd*15)/10;

     

  motorMode = mode;

  if (limit <= 0)

    motorMode = RELEASE;

  

  motorLeft.run(motorMode);

  motorRight.run(motorMode);

  motorLeft.setSpeed(spd);  

  motorRight.setSpeed(spd);  

  

  // stopped timer check and set

  stopped = (limit<=0);

  if (stopped)

    stoppedTimer = 1000;

}

  

void motors_forward(int limit, int angle)

{

  steer_toward(angle);

  set_motors(FORWARD, limit);

}

  

void motors_backward(int limit, int angle)

{

  steer_toward(angle);

  set_motors(BACKWARD, limit);

}

  

void steer_toward(int sangle)

{

  steeringAngle = sangle;

  servoSteering.write(140-sangle);

}

The Almost Finished Robot

BOTZERO !

Here is botZero, as it is right now … more mechanics refactoring is left for the near future, as I plan to install a front wheel encoder. I want to use this to measure distance traveled and experiment with dynamically constructing a presence map for navigational control. By that I mean, collect historical obstacle distance and heading samples and adjust those values over time based on position changes calculated from wheel encoder data.

Parts assembled on this robot:

2x Arduino Duemilanove
1x Adafruit Motorshield Kit
1x PING))) Ultrasonic Sensor
1x Hitachi HM55B Compass Module
1x Green LED
1x Mini single pole toggle switch (3-5A)
2x Small hobby servos (salvaged from my crap helicoptor)
1x Tamiya Double Gearbox Kit (70168)
2x Tamiya Narrow Tire Set 70145 (4 tires total)
1x Custom build steering fork assembly (found junk furniture caster and scrap aluminum)
1x 4" x 8" Thin sheet aluminum
1x PCB board (radio shack)
2x 9-volt battery holders
1x 9.6 volt NiMH rechargeable battery pack (purchased at local hobby shop)
1x Plastic Box (TB-3)

Complete source available here.